home *** CD-ROM | disk | FTP | other *** search
/ L' Effet Pommier 3 / L'Effet Pommier - Volume 03.iso / Graphismes / 3D / POV-Ray 3.0B5a PPC / POV-Ray 3.0B5a / POVSCN.Scenes / POV3DEMO / DEMO / AREALIT3.POV < prev    next >
Text File  |  1995-11-08  |  2KB  |  92 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // Illustrates how adaptive level can affect soft shadows
  3.  
  4. // The shadow on the left uses "adaptive 0" and shows some major shadow
  5. // artifacts causes by undersampling. As the adaptive level increases
  6. // the shadow become much more accurate. Note: This is a worst-case
  7. // example.
  8.  
  9. // Left   shadow - adaptive 0 (renders fastest)
  10. // Middle shadow - adaptive 1
  11. // Right  shadow - adaptive 2 (renders slowest)
  12.  
  13. #version 3.0
  14. global_settings { assumed_gamma 2.2 }
  15.  
  16. #include "colors.inc"
  17. #include "textures.inc"
  18.  
  19. // A back wall to cast shadows onto
  20. plane { -z, -20
  21.     pigment { Gray70 }
  22.     finish { Dull }
  23. }
  24.  
  25. #declare SpacingX = 20
  26. #declare Radius = 5
  27. #declare LightX = 15
  28. #declare LightY = 40
  29. #declare LightZ = -40
  30. #declare SRadius = 0
  31. #declare SFalloff = 11
  32.  
  33. #declare Object = difference {
  34.     box { <-6, -6, 0>, <6, 6, 0.5> rotate 45*z }
  35.     box { <-2.5, -2.5, -1>, <2.5, 2.5, 1> rotate 45*z }
  36.     pigment { Red }
  37.     finish { Shiny }
  38. }
  39.  
  40. object { Object translate -SpacingX*x }
  41.  
  42. light_source {
  43.     <0, LightY, LightZ> color White
  44.     area_light <15, 0, 0>, <0, 15, 0>, 17, 17
  45.     adaptive 0
  46.     jitter
  47.  
  48.     spotlight
  49.     point_at <-SpacingX, 0, 0>
  50.     tightness 0
  51.     radius SRadius
  52.     falloff SFalloff
  53. }
  54.  
  55. object { Object translate 0*x }
  56.  
  57. light_source {
  58.     <0, LightY, LightZ> color White
  59.     area_light <15, 0, 0>, <0, 15, 0>, 17, 17
  60.     adaptive 1
  61.     jitter
  62.  
  63.     spotlight
  64.     point_at <0, 0, 0>
  65.     tightness 0
  66.     radius SRadius
  67.     falloff SFalloff
  68. }
  69.  
  70. object { Object translate SpacingX*x }
  71.  
  72. light_source {
  73.     <0, LightY, LightZ> color White
  74.     area_light <15, 0, 0>, <0, 15, 0>, 17, 17
  75.     adaptive 2
  76.     jitter
  77.  
  78.     spotlight
  79.     point_at <+SpacingX, 0, 0>
  80.     tightness 0
  81.     radius SRadius
  82.     falloff SFalloff
  83. }
  84.  
  85. light_source { <0, -15, -120> color Gray10 }
  86.  
  87. camera {
  88.     location <0, -15, -120>
  89.     direction 2*z
  90.     look_at <0, -15, 0>
  91. }
  92.